ZX81 Programs


Read about, play, run, or list games, animations, and more. These are my programs from the ’80s to today.

ZX81 Program Listing

**STICK SHIFT**SLR/1985 (stickshift.p)


SYSTEM VARIABLES

PROG  : 16509
D-FILE: 17961
VARS  : 18754
E-LINE: 18755
STKBOT: 18755
STKEND: 18755


LEGEND

9999 means line number
PRINT means treat as KEYWORD P


PROGRAM LISTING

  10 REM **STICK SHIFT**SLR/1985
  20 PRINT "USEING THE ARROW KEY
S AND A GOODEYE, YOU STEER OVER 
A DANGEROUS STREET.  YOU SCORE P
OINTS BY THEMISSING OF OTHER CAR
S, OIL, AND SPIKES.  ALSO, THE S
IDE WALL WILCAUSE YOU TO LOSE PO
INTS IF HIT.USE THE 5 AND 8 KEYS
 TO TURN.   USE THE 6 AND 7 KEYS
 FOR SPEED."
  30 LET A$="H"
  40 LET B$="! "
  45 LET E$=" !"
  50 DIM C$(3,1)
  60 LET C$(1)="!"
  70 LET C$(2)="H"
  80 LET C$(3)="¶"
  90 PRINT ,,"PRESS ENTER TO BEG
IN..."
  95 PAUSE 4E4
 100 LET D$="PEEK (PEEK 16398+25
6*PEEK 16399)"
 110 LET S=0
 120 LET A=10
 130 LET X=15
 140 LET D=10
 150 LET SP=-1
 160 LET D2=10
 170 CLS
 180 FOR G=1 TO 15
 190 FOR H=1 TO D2
 200 SCROLL
 210 PRINT AT 0,X;A$;AT 21,A;B$;
AT 21,A+D;E$
 230 IF H=1 THEN PRINT AT 21,A+1
+(INT (RND*(D-1)+1));C$(INT (RND
*3+1))
 240 LET L$=INKEY$
 250 IF L$="6" OR L$="7" THEN
LET SP=(-1 AND L$="6")+(1 AND L$
="7")
 260 LET X=X-(L$="5" AND X>0)+(L
$="8" AND X<31)
 280 LET A=A+(INT (RND*3-1))
 290 LET A=A+(A<0)-(A+D+1>31)
 300 IF SP<0 THEN LET L=SIN PI+
SIN PI
 310 PRINT AT 1,X;
 320 LET P=VAL D$
 330 LET S=S+(SP>0)-(P=128)
 340 IF P<>0 AND P<>128 THEN
GOTO 500
 350 NEXT H
 360 LET S=S+5
 370 NEXT G
 380 SCROLL
 390 PRINT "SCORE:";S
 400 SCROLL
 410 PRINT "GOOD DRIVE,KEEP GOIN
G..."
 420 PAUSE 200
 430 LET D=D-(D>4)
 440 LET D2=D2-(D2>3)
 450 CLS
 460 GOTO 170
 500 SCROLL
 510 PRINT "SCORE:";S
 520 SCROLL
 530 PRINT "YOU CRASHED AND DIED
..."
 540 SCROLL
 550 PRINT "GAME OVER"
 560 SCROLL
 570 PRINT "PRESS ENTER TO START
 AGAIN..."
 580 PAUSE 4E4
 590 CLS
 600 RUN
 700 SAVE "STICKSHIFT"
 710 RUN